# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=bluefish
pkgver=2.2.17
pkgrel=1
pkgdesc='A powerful HTML editor for experienced web designers and programmers'
arch=('x86_64')
url='http://bluefish.openoffice.nl/'
license=('GPL3')
depends=('gtk3' 'enchant' 'python')
makedepends=('gucharmap' 'intltool')
optdepends=('gucharmap: for using the charmap plugin')
install=$pkgname.install
source=("https://www.bennewitz.com/$pkgname/stable/source/$pkgname-$pkgver.tar.bz2"{,.sig})
validpgpkeys=(64979277BAFF2D4CB637AC3B291C63A6B78DFBA1) # Olivier Sessink <olivier@bluefish.openoffice.nl>
sha512sums=('9815316f265c48ea37afa513e6530470f4c4af37f27ddf0873a8b27c5a3f58b3927614e7465e950b4eb05a93f3daab458ccbc70547484539568c3ca1499f6a46'
            'SKIP')

prepare() {
  cd $pkgname-$pkgver
  autoreconf -vif
}

build() {
  cd $pkgname-$pkgver

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --enable-spell-check \
    --disable-update-databases \
    --disable-xml-catalog-update

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install
}
