# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-power-manager
pkgver=43.0
pkgrel=3
pkgdesc="System power information and statistics"
url="https://gitlab.gnome.org/GNOME/gnome-power-manager"
arch=(x86_64)
license=(GPL)
depends=(gtk4 upower dconf)
makedepends=(git meson)
source=("git+https://gitlab.gnome.org/GNOME/gnome-power-manager.git#commit=GNOME_POWER_MANAGER_${pkgver//./_}")
b2sums=('f05008bdabef550f911fbd87ead26da61f23403d759dcd746b37652ea4b56094b08ee7f7109d6876089f5f8f93846e39cc40a74fb6910968c7249839f209db77')

prepare() {
  cd $pkgname

  # Port to GTK4
  # https://gitlab.gnome.org/GNOME/gnome-power-manager/-/merge_requests/22
  git cherry-pick -n a965912774a58bae42890d25b46791eb347d944a

  # Fix icon name 
  # https://gitlab.gnome.org/GNOME/gnome-power-manager/-/merge_requests/23
  git cherry-pick -n b92b61dd4f99b734feac3e60ea46ef3f29243cb6

  # Use GApplication to parse command line options 
  # https://gitlab.gnome.org/GNOME/gnome-power-manager/-/merge_requests/27
  git cherry-pick -n 5b47a4b89800c95d814444f46cdc446d5d7d8d01

  # Add D-Bus service file 
  # https://gitlab.gnome.org/GNOME/gnome-power-manager/-/merge_requests/29
  git cherry-pick -n 3e822609835d3f5b7e757d959787f03bc7885dc2
  # https://gitlab.gnome.org/GNOME/gnome-power-manager/-/merge_requests/31
  git cherry-pick -n 4d9c41ce8aa6528d4837da6ef97e24841e59e182

  # Don't hide in other desktop environments
  # https://gitlab.gnome.org/GNOME/gnome-power-manager/-/merge_requests/30
  git cherry-pick -n 91f5a956b3c3a681d809675824409182831f3454
}

build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}

# vim:set sw=2 sts=-1 et:
